From 37081f0a1f804cda1cc902f0539cc02ca63d22a9 Mon Sep 17 00:00:00 2001
From: Adam Dickmeiss <adam@indexdata.dk>
Date: Wed, 21 Feb 2001 11:00:05 +0000
Subject: [PATCH] Added yaz.m4.

---
 yaz.m4 |   48 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 yaz.m4

diff --git a/yaz.m4 b/yaz.m4
new file mode 100644
index 0000000..db902b0
--- /dev/null
+++ b/yaz.m4
@@ -0,0 +1,48 @@
+## $Id: yaz.m4,v 1.1 2001-02-21 11:00:05 adam Exp $
+## 
+# Use this m4 funciton for autoconf if you use YAZ in your own
+# configure script.
+# YAZ_INIT
+
+AC_DEFUN([YAZ_INIT],
+[
+	AC_SUBST(YAZLIB)
+	AC_SUBST(YAZLALIB)
+	AC_SUBST(YAZINC)
+	AC_SUBST(YAZVERSION)
+	yazconfig=NONE
+	yazpath=NONE
+	AC_ARG_WITH(yazconfig, [  --with-yazconfig=DIR    yaz-config in DIR (example /home/yaz-1.7)], [yazpath=$withval])
+	if test "x$yazpath" != "xNONE"; then
+		yazconfig=$yazpath/yaz-config
+	else
+		for i in ../yaz* ../yaz; do
+			if test -d $i; then
+				if test -r $i/yaz-config; then
+					yazconfig=$i/yaz-config
+				fi
+			fi
+		done
+		if test "x$yazconfig" = "xNONE"; then
+			AC_PATH_PROG(yazconfig, yaz-config, NONE)
+		fi
+	fi
+	AC_MSG_CHECKING(for YAZ)
+	if $yazconfig --version >/dev/null 2>&1; then
+		YAZLIB=`$yazconfig --libs $1`
+		# if this is empty, it's a simple version YAZ 1.6 script
+		# so we have to source it instead...
+		if test "X$YAZLIB" = "X"; then
+			. $yazconfig
+		else
+			YAZLALIB=`$yazconfig --lalibs $1`
+			YAZINC=`$yazconfig --cflags $1`
+			YAZVERSION=`$yazconfig --version`
+		fi
+		AC_MSG_RESULT($yazconfig)
+	else
+		AC_MSG_RESULT(Not found)
+		YAZVERSION=NONE
+	fi
+])
+	
-- 
1.7.10.4